// LetterPaint based on Box Fitting Image
// j.tarbell   May, 2004 Albuquerque, New Mexico
// complexification.net
// novikod.com  D.Novikov November, 2009
int num = 0;
int maxnum = 2000;
int dimx = 1700;
int dim = 2600;
int time;
PFont font;
String[] letters = {"АЛФАВИТ", "А", "Л", "Ф", "А", "В", "И", "Т", "БУКВА", "Б", "У", "К", "В","Ы"};
int count = 0;
int deltaC = 40; 

Box[] boxes;

// background image
PImage ab;



// MAIN -----------------------------------------------------------

void setup() {
  size(dimx,dim,P3D);
  colorMode(HSB, 255);

  font = loadFont("Verdana-Bold-72.vlw");
  //textMode(SHAPE);

  rectMode(CENTER);
  noStroke();

  // create boxes
  boxes = new Box[maxnum];

  // load background image
  ab = loadImage("portrait3.jpg");

  resetAll();
}

void draw() {
  for (int n=0;n<num;n++) {
    boxes[n].draw();     
  }  
}

void mousePressed() {
  save("portrait3.tif");
  resetAll();
}

void resetAll() {      
  // stop drawing
  num=0;

  // clear screen, prepare canvas
  background(255);
  // initialize just three starting boxes
  makeNewBox();
  makeNewBox();
  makeNewBox();

}


void makeNewBox() {
  if (num<maxnum) {
    boxes[num] = new Box(count);
    num++;
    count++;
    if (count == letters.length) {
      count=0;
    }
  }
}

color readBackground(int x, int y) {
  // translate into ba image dimensions
  int ax = int(x * (ab.width*1.0)/dimx);
  int ay = int(y * (ab.height*1.0)/dim);
  color c = ab.pixels[ay*ab.width+ax];
  return c;
}


// OBJECTS ------------------------------------------------------


// space filling box
class Box {

  int x;
  int y;
  int d;
  int H;
  int W;
  boolean selector;
  color myc;
  int letterSize = 40;
  boolean okToDraw;
  boolean chaste = true;
  int countB = 0;
  int factor = 1;
  float coef;

  Box(int _count) {
    countB = _count;
    selfinit();
    if (letters[countB].length() > 1) {
      factor = round(letters[countB].length() * coef);
      if (factor == letters[countB].length()) { print(factor + " !!!\n");}
      //letterSize = letterSize*factor;
    }
  }

  void selfinit() {
    // position
    okToDraw = false;    
    x = int(random(dimx));
    y = int(random(dim));
    d = 0;
    if (random(1) > 0.75) {
      selector = true;
      coef = 1.2;
    } 
    else{
      selector = false;
      coef = 0.84;
    }
    
    myc = readBackground(x,y);
  }

  void draw() {
    expand();
    if (factor == letters[countB].length() && letters[countB].length() != 1) { print(factor + " 2!!!\n");}
    if (okToDraw) {
      fill(255);
      rect(x,y,W-2,H-1);
      fill(myc);
      switch (d){
      case 2 :
        textFont(font, 5);
        break;
      case 4 :
        textFont(font, 5);
        break;
      default :
        textFont(font, d);
        break;
      }
      textAlign(CENTER, CENTER);
      text(letters[countB], x, y, W, H);
    }
  }

  void expand() {
    // assume expansion is ok
    d+=2;
    if (selector) {
      H = d*factor;
      W = d;
    } 
    else{
      H = d;
      W = d*factor;
    }
    int obstructions = 0;
    for (int j=int(x-W/2);j<int(x+W/2);j++) {
      int k=int(y-H/2);
      obstructions += checkPixel(j,k);
      k=int(y+H/2);
      obstructions += checkPixel(j,k);
    }      
    for (int k=int(y-H/2);k<int(y+H/2);k++) {
      int j=int(x-W/2);
      obstructions += checkPixel(j,k);
      j=int(x+W/2);
      obstructions += checkPixel(j,k);
    }  
    if (d > letterSize) {
      obstructions = 1;
    }
    if (obstructions>0) {
      // reset
      selfinit();    
      if (chaste) {
        makeNewBox();
        chaste = false;
      }
    } else {
      okToDraw = true;
    }
  }

  int checkPixel(int x, int y) {
    if ((x>0) && (x<dimx) || (x==0) || (x==dimx-1)) {
      if ((y>0) && (y<dim) || (y==0) || (y==dim-1)) {

        color c = readBackground(x,y);
        color f = get(x, y);
        float deltaHue;
        //hue 0-360 range issue check
        if ((255 - hue(c)) < deltaC && (hue(myc) < deltaC)) {
          deltaHue = 255 - hue(c) + hue(myc);
        }
        if ((255 - hue(myc)) < deltaC && (hue(c) < deltaC)) {
          deltaHue = 255 - hue(myc) + hue(c);
        } else {
          deltaHue = abs(hue(c)-hue(myc));
        }
        if (deltaHue > deltaC || (abs(saturation(c)-saturation(myc)) > (deltaC+20)) || (abs(brightness(c)-brightness(myc)) > deltaC) || (saturation(f) > 0) || (brightness(f)<235)) { 
          return 1;
        } 
        else {
          return 0;

        }
      }
    }
    return 0;
  }

  
}